Source Code

//-----------------------------------------
// LScript Image Filter - www.StephenCulley.co.uk - Grain
//

@version 2.5
@warnings
@script image

Grain;

create
{
    Grain = 10;
    setdesc("www.StephenCulley.co.uk - Grain : " + Grain);
}

process: ifo
{

if(runningUnder() != SCREAMERNET)
    moninit(ifo.height);

    for(i = 1;i <= ifo.height;++i)
    {
        for(j = 1;j <= ifo.width;++j)
        {

         Temp = random(-Grain,Grain);  

         ifo.red[j,i] = ifo.red[j,i] + ((1/256) * Temp);
         ifo.green[j,i] = ifo.green[j,i] + ((1/256) * Temp);
         ifo.blue[j,i] = ifo.blue[j,i] + ((1/256) * Temp);

         }

if(runningUnder() != SCREAMERNET)
    if(monstep())
    return;

    }
}

load: what,io
{
    if(what == SCENEMODE)
    {
        Grain = integer(io.read());
        setdesc("www.StephenCulley.co.uk - Grain : " + Grain);
    }
}

save: what,io
{
    if(what == SCENEMODE)
    {
        io.writeln(Grain);
    }
}

options
{
    reqbegin("Grain");
    c1 = ctlinteger("Amount",Grain);
    return if !reqpost();
    Grain = getvalue(c1);
    setdesc("www.StephenCulley.co.uk - Grain : " + Grain);
    reqend();
}